Using the InboundEmail Object

For every email the Apex email service domain receives, Salesforce.com creates a separate InboundEmail object that contains the contents and attachments of that email. You can use Apex classes that implement the Messaging.InboundEmailHandler interface to handle an inbound email message. Using the handleInboundEmail method in that class, you can access an InboundEmail object to retrieve the contents, headers, and attachments of inbound email messages, as well as perform many functions.

Example 1: Create Tasks for Contacts

The following is an example of how you can look up a contact based on the inbound email address and create a new task.

 global class CreateTaskEmailExample implements Messaging.InboundEmailHandler {
 
  global Messaging.InboundEmailResult handleInboundEmail(Messaging.inboundEmail email, 
                                                       Messaging.InboundEnvelope env){
 
  // Create an inboundEmailResult object for returning the result of the Apex Email Service  
    
    Messaging.InboundEmailResult result = new Messaging.InboundEmailResult();
 

  String myPlainText= '';
  
  // Add the email plain text into the local variable   
    
 
  myPlainText = email.plainTextBody;
 
  // New Task object to be created  
    
 
  Task[] newTask = new Task[0];
 
  // Try to lookup any contacts based on the email from address  
    
  // If there is more than 1 contact with the same email address,  
    
  // an exception will be thrown and the catch statement will be called.  
    
  try {Contact vCon = [Select Id, Name, Email
    From Contact
    Where Email = :email.fromAddress
    Limit 1];
  
  // Add a new Task to the contact record we just found above.  
    
  newTask.add(new Task(Description =  myPlainText,
       Priority = 'Normal',
       Status = 'Inbound Email',
        Subject = email.subject,
        IsReminderSet = true,
        ReminderDateTime = System.now()+1,
        WhoId =  vCon.Id));
 
 // Insert the new Task   
    
 insert newTask;
  
 
 System.debug('New Task Object: ' + newTask );
 
  }
  // If an exception occurs when the query accesses   
    
  // the contact record, a QueryException is called.  
    
  // The exception is written to the Apex debug log.  
    
 catch (QueryException e) {System.debug('Query Issue: ' + e);
 }
 
 // Set the result to true. No need to send an email back to the user   
    
 // with an error message  
    
 
    result.success = true;
 
 // Return the result for the Apex Email Service  
    
    return result;
 
  }
 }